MCCustomSkinLoader/BuildScripts/remap.gradle

/**
 * Gradle Script for Remap
 * Designed for remapping jar.
 * Remap Jar: mcp<->srg<->notch
 */

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

import net.md_5.specialsource.JarMapping
import net.md_5.specialsource.JarRemapper
import net.md_5.specialsource.provider.JarProvider
import net.md_5.specialsource.provider.JointProvider


void reobfSrgToNotch() {
    def srgName = "${archivesBaseName}-${version}-srg.jar"
    def notchName = srgName.replace('-srg', '')
    if (config.srg_notch_map == null) {
        //Default Map
        def mcpName = srgName.replace('-srg', '-dev')
        applySpecialSource(srgName, mcpName, getDefaultMap("srg-mcp"))
        applySpecialSource(mcpName, notchName, getDefaultMap("mcp-notch"))
    } else {
        //Custom Map
        applySpecialSource(srgName, notchName, config.srg_notch_map)
    }
}

void applySpecialSource(String inputName, String outputName, String mapFile) {
    def mapping = new JarMapping()
    def srgFile = file(mapFile)
    def inputFile = file("build/libs/${inputName}")
    def outputFile = file("build/libs/${outputName}")
    def remapper = new JarRemapper(null, mapping)
    def inputJar = net.md_5.specialsource.Jar.init(inputFile)
    def inheritanceProviders = new JointProvider()
    def jarProvider = new JarProvider(inputJar)
    inheritanceProviders.add(jarProvider)
    mapping.loadMappings(srgFile)
    mapping.setFallbackInheritanceProvider(inheritanceProviders)
    remapper.remapJar(inputJar, outputFile)
}

String getDefaultMap(String srgType) {
    def mcpVersion = minecraft.mappings.replace('_', "/")
    return System.getProperty('user.home') + "/.gradle/caches/minecraft/de/oceanlabs/mcp/mcp_${mcpVersion}/${config.forge_mc_version}/srgs/${srgType}.srg"
}

ext {
    reobfSrgToNotch = this.&reobfSrgToNotch
}