LuckPerms/neoforge/loader/build.gradle

plugins {
    alias(libs.plugins.shadow)
    alias(libs.plugins.moddevgradle)
    id("java-library")
}

tasks.withType(JavaCompile).configureEach {
    options.release = 25
}

neoForge {
    version = project.neoForgeVersion
    validateAccessTransformers = true

    runs {
        client {
            client()
        }
        server {
            server()
        }
    }
}

configurations {
    shade
    implementation.extendsFrom shade
}

dependencies {
    shade project(':api')
    shade project(':common:loader-utils')
}

build {
    dependsOn(":neoforge:build")
}

jar {
    manifest {
        attributes(
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Implementation-Title': 'LuckPerms',
                'Implementation-Vendor': 'LuckPerms',
                'Implementation-Version': project.ext.fullVersion,
                'Specification-Title': 'luckperms',
                'Specification-Vendor': 'LuckPerms',
                'Specification-Version': '1'
        )
    }
}

processResources {
    filesMatching('META-INF/neoforge.mods.toml') {
        expand 'version': project.ext.fullVersion
    }
}

shadowJar {
    archiveFileName = "LuckPerms-NeoForge-${project.ext.fullVersion}.jar"
    configurations = [project.configurations.shade]

    from {
        project(':neoforge').tasks.shadowJar.archiveFile
    }

    dependencies {
        include(dependency('net.luckperms:.*'))
        include(dependency('me.lucko.luckperms:.*'))
    }
}

artifacts {
    archives shadowJar
}